gusucode.com > 耐品图片管理系统 标准版A > 耐品图片管理系统 标准版A/Show.asp

    <!--#include file="Inc/clsSetting.asp" -->
<%
'===============================================================
' 著作权号：中国国家版权局著作权登记号2004SR07385
' 版权所有：深圳市耐品科技开发有限公司 www.naipin.com
' 联系电话：0755-26611119　81234844　81234845
' 联系手机：13316911914
' 联系邮箱：naipin@naipin.com
'===============================================================

Dim FileName,MyImage,LinkUrl,RootPath,ShowType,DiskName

MyImage = "Images/logobbs.gif"
LinkUrl = Lcase(Request.ServerVariables("HTTP_REFERER"))
FileName = Trim(Request.QueryString("f"))
DiskName = Trim(Request.QueryString("d")&"")
ShowType = UCase(Trim(Request.QueryString("s")))

Select Case ShowType
	Case "S","D":RootPath = Config.ImagePath(0)
	Case "I":RootPath = Config.ImagePath(1)
	Case "P":RootPath = Config.ImagePath(2)
End Select

If LinkUrl="" Or InStr(LinkUrl,Lcase(Request.ServerVariables("SERVER_NAME")))<=0 Or FileName="" Then
	If InStr(LinkUrl,"www.netpic.cn")<=0 And InStr(LinkUrl,"www.netpic.net")<=0 And InStr(LinkUrl,"www.naipin.com")<=0 And InStr(LinkUrl,"www.maitu.net")<=0 Then
		Call DownFile(Server.MapPath(MyImage))
	Else
		Call DownFile(Server.MapPath(RootPath&FileName))
	End If
Else
	Call DownFile(Server.MapPath(RootPath&FileName))
End If

Sub DownFile(strFile)
	On error resume next
	Server.ScriptTimeOut=999999
	Dim Stream,fso,File,FileSize,FileName,FileType
	
	Response.Clear
	Set Stream = Server.CreateObject("ADODB.Stream") 
	Stream.Open
	Stream.Type = 1 
	Set fso = Server.CreateObject("Scripting.FileSystemObject") 
	If Not fso.FileExists(strFile) Then
		Call DownFile(Server.MapPath(MyImage))
		Exit Sub
	End If
	Set File = fso.GetFile(strFile)
	FileSize = File.Size:FileName = LCase(File.Name)
	FileExt = Mid(FileName,InStrRev(FileName,".")+1)
	Stream.LoadFromFile(strFile)
	If err Then Response.Write Err.Description
	Set fso = Nothing
	
	Select Case FileExt
	Case "doc":FileType = "vnd.ms-word"
	Case "xls":FileType = "vnd.ms-excel"
	Case "ppt":FileType = "vnd.ms-powerpoint"
	Case "gif":FileType = "image/gif"
	Case "jpg":FileType = "image/jpeg"
	Case "bmp":FileType = "image/bmp"
	Case "png":FileType = "image/png"
	Case Else:FileType = "octet-stream"
	End Select
	
	If Config.Settings(30) = "1" Then
		If DiskName<>"" Then FileName = DiskName
	End If
	
	Dim Data
	Data = Stream.Read
	Stream.Close
	Set Stream = Nothing
	If Response.IsClientConnected Then
		Response.ContentType = "Application/"&FileType
		If ShowType = "D" Then 
			Response.AddHeader "Content-Disposition", "attachment; filename=" & FileName
		End If
		Response.AddHeader "Content-Length", FileSize
 		Response.CharSet = "UTF-8" 
		Response.ContentType = "application/octet-stream"
		Response.BinaryWrite Data
		Response.Flush
	End If
End Sub
%>